Forum

Basic32 is tested with the ILI9341 it seems to me that the M5Stack Core1 has the ILI9342C.
Most likely it’s enough to change something in the BASIC listing to center it, because since I don’t have it, I can’t test it.
I see that something is already displayed, which is a good sign. Try it and let me know if you manage to get it working.

report

20 TIMEZONE DE
30 SYNCNTP
40 REM ==== ANALOG CLOCK ====
50 ILI SPEED 80 'IF YOU SEE ARTIFACTS, DROP TO 60 OR 40
60 ILI INIT 14 27 33 1
70 ILI LED 32 1
80 ILI SETBGCOLOR 0 0 0
90 ILI CLEAR
can i do another parameter to see the right clock?

report

If you want see right clock you connect wifi: 10 WIFI "SSID" "PASSWORD"
20 TIMEZONE IT
30 SYNCNTP
40 REM ==== ANALOG CLOCK ====
50 ILI SPEED 80 'IF YOU SEE ARTIFACTS, DROP TO 60 OR 40
60 ILI INIT 17 16 5 3
70 ILI LED 32 1
80 ILI SETBGCOLOR 0 0 0
90 ILI CLEAR
100 REM ==== DIGITAL ====
110 XDIG = 4
120 YDIG = 4
130 SDIG = 2
140 REM ==== CENTER AND DIMENSIONS ====
150 CX = 160
160 CY = 130
170 R = 90
180 FIRST = 1
190 REM ==== DRAW THE DIAL ONCE ====
200 GOSUB 250
210 ILI DRAW
220 REM ==== MAIN LOOP ====
230 GOSUB 370
240 GOTO 230
250 REM ==== DRAW THE DIAL ====
260 ILI CIRCLE CX CY R 255 255 255 0
270 FOR H = 0 TO 11
280 ANG = H * 30
290 A = 90 - ANG
300 XOUT = CX + R * COS(A)
310 YOUT = CY - R * SIN(A)
320 XIN = CX + (R-10) * COS(A)
330 YIN = CY - (R-10) * SIN(A)
340 ILI LINE XIN YIN XOUT YOUT 255 255 255 0
350 NEXT H
360 RETURN
370 REM ==== UPDATE HANDS + DIGITAL ====
380 HRS = TIMEH
390 MINS = TIMEM
400 SECS = TIMES
410 HH12 = HRS
420 HH12 = HH12 - INT(HH12 / 12) * 12
430 ANG_H = HH12 * 30.0 + (MINS * 0.5)
440 ANG_M = MINS * 6.0
450 ANG_S = SECS * 6.0
460 AH = 90.0 - ANG_H
470 AM = 90.0 - ANG_M
480 AS = 90.0 - ANG_S
490 LH = R * 0.5
500 LM = R * 0.75
510 LS = R * 0.9
520 XH = CX + LH * COS(AH)
530 YH = CY - LH * SIN(AH)
540 XM = CX + LM * COS(AM)
550 YM = CY - LM * SIN(AM)
560 XS = CX + LS * COS(AS)
570 YS = CY - LS * SIN(AS)
580 REM ==== ERASE OLD HANDS ====
590 IF FIRST = 0 THEN ILI LINE CX CY OLD_XH OLD_YH 0 0 0 0
600 IF FIRST = 0 THEN ILI LINE CX CY OLD_XM OLD_YM 0 0 0 0
610 IF FIRST = 0 THEN ILI LINE CX CY OLD_XS OLD_YS 0 0 0 0
620 REM ====RESTORE CIRCLE + MARKERS ====
630 IF FIRST = 0 THEN GOSUB 250
640 REM ==== DRAW NEW HANDS ====
650 ILI LINE CX CY XH YH 255 255 0 0
660 ILI LINE CX CY XM YM 0 255 0 0
670 ILI LINE CX CY XS YS 255 0 0 0
680 ILI FILLCIRCLE CX CY 4 255 0 0 0
690 REM ==== SAVE POSITIONS ====
700 OLD_XH = XH : OLD_YH = YH
710 OLD_XM = XM : OLD_YM = YM
720 OLD_XS = XS : OLD_YS = YS
730 FIRST = 0
740 REM ==== DIGITAL TOP-LEFT ====
750 T$ = ""
760 IF HRS < 10 THEN T$ = T$ + "0" + STR$(HRS) ELSE T$ = T$ + STR$(HRS)
770 T$ = T$ + ":"
780 IF MINS < 10 THEN T$ = T$ + "0" + STR$(MINS) ELSE T$ = T$ + STR$(MINS)
790 T$ = T$ + ":"
800 IF SECS < 10 THEN T$ = T$ + "0" + STR$(SECS) ELSE T$ = T$ + STR$(SECS)
810 ILI FILLRECT 0 0 140 20 0 0 0 0
820 ILI TEXT XDIG YDIG SDIG T$ 255 255 255 0
830 REM ==== SINGLE FLUSH ====
840 ILI DRAW
850 REM ==== WAIT FOR NEXT SECOND ====
860 S0 = SECS
870 S1 = TIMES
880 IF S1 = S0 THEN GOTO 870
890 RETURN

report